chroniclesofreg/missingwand.inform/Source/story.ni

"Mystery of the Missing Wand" by "Masterful Interactions".

Chapter 0 - Game Setup and License

[ Copyright (C) 2022  William R. Moore <william@nerderium.com> and Olivia BE Moore

	This program is free software: you can redistribute it and/or modify
	it under the terms of the GNU General Public License as published by
	the Free Software Foundation, version 3 of the License.

	This program is distributed in the hope that it will be useful,
	but WITHOUT ANY WARRANTY; without even the implied warranty of
	MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	GNU General Public License for more details.

	You should have received a copy of the GNU General Public License
	along with this program. If not, see <https://www.gnu.org/licenses/>. ]

The story description is "Where in the world is the missing wand and can you find it before it is too late?".
The release number is 2.
Release along with cover art, interpreter, library card, and source text.

A person has a number called health. The health of the player is 20.
Definition: a person is dead if their health < 1

Asking someone about something is speech. Telling someone about something is speech. Answering someone that something is speech. Asking someone for something is speech.
The block giving rule is not listed in the check giving it to rules.

When play begins:
  now the right hand status line is "Health: [health of the player]".

Chapter 1 - Figures

Figure of Heroine is the file "heroine.jpg".
Figure of Reg is the file "reg-werewolf.jpg".
Figure of Skeleton is the file "skeleton.jpg".
Figure of Ghost is the file "ghost.jpg".
Figure of Gorilla is the file "gorilla.jpg".
Figure of Boogeyman is the file "boogeyman.jpg".

Chapter 2 - Persons

Reg the Good Werewolf is a person. They are in Reg's House Living Room. The description is "A towering werewolf sporting blue jeans and a T-shirt. He has a friendly smile on his face.".

[ Monsters ]
A monster is a kind of person.
A skeleton is a monster. It is in Western Graveyard. The health of the skeleton is 5. The description is "The skinless creature has a scary, grinning face that frightens you to the core.".
A ghost is a monster. It is in Eastern Graveyard. The health of the ghost is 5. The description is "The frightening and nearly invisible apparition makes you want to run and hide.".
A 100 ft undead gorilla is a monster. It is in the Northern Graveyard. The health of the 100 ft undead gorilla is 15. The description is "Before you is a 100 foot undead gorilla with no pupils and just white eyes! You don't know how it got here and it is blood-chilling to look at the undead face.".
Boogeyman is a monster. It is in Boogeyman's House. The health of Boogeyman is 30. The description is "You see the boogeyman. They are the be-all, end-all of baddies with claws and sharp teeth used to eat little children.".

Chapter 3 - Places

[ Reg's House ]
Reg's House Living Room is a room. It is below Reg's House Upstairs. It is north of Reg's House Kitchen. The description is "The living room of Reg's House is very clean and large. The kitchen is to the south. There are stairs leading up.".
Reg's House Kitchen is a room. The description is "The lightly-colored, hardwood floor, the white, wooden cabinets, and granite countertop just simply sparkles despite being in an area primarily used in the preparation of messy foods.".
Reg's House Upstairs is room. The description is "The upstairs has three doors: one north, one west, and one east."
Briley's Bedroom is a room. It is north of Reg's House Upstairs. The description is "The room is an utter nightmare of heavy metal CDs and role-playing game stuff. Be careful where you walk!".
Reg's Bedoom is a room. It is west of Reg's House Upstairs. The description is "The bedroom is tidy and orderly with lace curtains on both windows that face outside. The bed looks like it is always made and ready to sleep in.".
Sparkle's Bedoom is a room. It is east of Reg's House Upstairs. The description is "The bedroom is full of stuffed animals, pink bunny toys, and many girl's things. The window has fancy, pink curtains on it.".

[ Graveyard ]
Western Graveyard is a room. It is west of Graveyard Entrance. The description is "The row after row of old headstones that are falling apart is frightening.".
Eastern Graveyard is a room. It is east of Graveyard Entrance. The description is "There are row after row of old headstones that are falling apart and look is frightening.".
Northern Graveyard is a room. It is north of Graveyard Entrance. The description is "The row after row of old headstones that are falling apart is frightening.".
Graveyard Entrance is a room. The description is "Welcome to the entrance of the graveyard. You see here thousands of headstones in various states. There are paths leading north, east, and west.".

[ Boogeyman's House ]
Boogeyman's House is a room. The description is "The house of the famous boogeyman looks tiny and cramped. You feel like the walls are closing in on you just by standing in it.".

Chapter 4 - Things

The golden earrings is a thing. It is wearable. The description is "These golden earings, when worn, look like they could stop a boogeyman from hurting you.".
The wand is a thing. The description is "The black, twisted wand looks like it could be the one that Reg wants.".
A taco is a thing. The description is "This taco has just the right amount of all the ingredients. In fact, it just might be most perfect taco. It looks delicious.".

A die is a kind of thing. A die has a number called sides.
The tetrahedron is a die. Understand "tetra" as tetrahedron. It is in Briley's Bedroom. The sides of tetrahedron is 4. The description is "This pyramid shaped plastic shape is silver colored. It looks like it wants to be rolled.".
The hexahedron is a die. Understand "hexa" as hexahedron. It is in Briley's Bedroom. The sides of hexahedron is 6. The description is "This cube shaped plastic shape is silver colored. It looks like it wants to be rolled.".
The octohedron is a die. Understand "octo" as octohedron. It is in Briley's Bedroom. The sides of octohedron is 8. The description is "This eight-sided plastic shape looks like two pyramids connected at the bottom and is silver colored. It looks like it wants to be rolled.".
The decahedron is a die. Understand "deca" as decahedron. It is in Briley's Bedroom. The sides of decahedron is 10. The description is "This ten-sided plastic shape looks like two diamonds connected at the tops and is silver colored. It looks like it wants to be rolled.".
The dodecahedron is a die. Understand "dodeca" as dodecahedron. It is in Briley's Bedroom. The sides of dodecahedron is 12. The description is "This twelve-sided plastic shape looks like a soccer ball and is silver colored. It looks like it wants to be rolled.".

Reg's TV is a thing. It is fixed in place. It is in Reg's House Living Room. The description is "A flat screen QLED TV with black trim. It is fixed onto the wall.".

Chapter 5 - Actions

Table of Help Commands
command	description
"north"	"Move north"
"south"	"Move south"
"east"	"Move east"
"west"	"Move west"
"northeast"	"Move northeast"
"northwest"	"Move northwest"
"southeast"	"Move southeast"
"southwest"	"Move southwest"
"up"	"Move up"
"down"	"Move down"
"look"	"Looks around at current location"
"save"	"Save state to a file"
"restore"	"Restores a saved state"
"restart"	"Restarts the game"
"verbose"	"Gives full description after each command"
"score"	"Displays score and ranking"
"diagnostic"	"Give description of health"
"brief"	"Give a description upon first entering an area"
"superbrief"	"Never describe an area"
"quit"	"Quit game"
"climb"	"Climbs (up)"
"g"	"Redo last command"
"go (direction)"	"Go towards direction (west/east/north/south/in/out/into)"
"enter"	"In to the place"
"in"	"Go into something"
"out"	"Go out of the place"
"hi/hello"	"Say hello"
"get/take (item)"	"Removes item from current room and places it in your inventory"
"get/take all"	"Takes all takeable objects in room"
"throw (item) at (location)"	"Throws the item at something"
"open (container)"	"Opens the container, whether it is in the room or your inventory"
"open (exit)"	"Opens the exit for travel"
"read (item)"	"Reads what is written on readable item"
"drop (item)"	"Removes item from inventory and places it in current room"
"put (item) in (container)"	"Removes item from inventory and places it in container"
"turn (control) with (item)"	"Attempts to operate the control with the item"
"turn on (item)"	"Turns on the item"
"turn off (item)"	"Turns the item off"
"move (object)"	"Moves a large object that cannot be picked up"
"attack (creature) with (item)"	"Attacks creature with the item"
"examine (object)"	"Examines, or looks, at an object or item or location"
"inventory"	"Shows contents of the inventory"
"eat"	"Eats item (specifically food)"
"shout"	"Shout it out (shout it out loud)"
"close (Door)"	"Closes door"
"tie (item) to (object)"	"Ties item to object"
"pick (item)"	"Take/get item"
"kill self with (weapon)"	"Humorously commits suicide"
"break (item) with (item)"	"Breaks item"
"kill (creature) with (item)"	"Attacks creature with the item"
"drink"	"Drink an item"
"smell"	"Smell an item"
"cut (object/item) with (weapon)"	"Comment: Strange concept, cutting the (object/item). If (object/item)=self then you commit suicide"
"listen (target)"	"Listens to a creature or an item"
"slap (target)"	"Slap the target viciously."
"poke (target)"	"Poke a target."
"use (thing) on (other thing)"	"Use an object on a thing."
"roll (die)"	"Roll a die."

Understand "help" as helping. Helping is an action applying to nothing.

After helping:
	say "You like help?  Here we go!:[paragraph break]";
	repeat through Table of Help Commands:
		say "[bold type][command entry][roman type]: [description entry][line break]".

Table of Television Responses
Response
"Where's Waldo? He's 5 foot 10 inches with a red and white striped shirt, red and white striped hat, propensity to hide. Please, let us know. His family misses him."
"Corey Corem has put out his latest album containing all new classics. You can find 'It's a Plea Bargain, Baby!' is available on all your favorite streaming platforms and local stores."
"And that, folks, was the latest trailer for 'Hands Off My Burrito!', the lastest film in the Billy Davis Cinematic Universe. Well, it was exactly what I expected. Let's just say!"
"The ex-wife of Firenze Prumt was found dead today in an apparent suicide while falling down the stairs. This comes days after said she has dirt on his activities many have claimed are illegal in nature."
"Enjoy the newest, hippest, greatest chip in town: Mumford Chips. Mumford Chips: the chips that make you...gruuuuuuunt! Made by S.C. Johnson Wax."
"Drink Pepso! The only drink made with real pepsin!"

After examining TV:
	let rr be a random number from 1 to number of rows in Table of Television Responses;
	say "The TV says '[Response in row rr of Table of Television Responses]'".

Before examining the player:
	display the Figure of Heroine.

Before examining Reg the Good Werewolf:
	display the Figure of Reg.

Before examining the 100 ft undead gorilla:
	display the Figure of Gorilla.

Before examining skeleton:
	display the Figure of Skeleton.

Before examining ghost:
	display the Figure of Ghost.

Before examining Boogeyman:
	display the Figure of Boogeyman.

Understand "use [something preferably held] on [something]" as using on. Using on is an action applying to one visible thing and one visible thing.

Carry out using on:
	If the noun is a die:
		let result be a random number from 1 to the sides of the noun;
		say "You have rolled [result] on [the noun].";
		if the second noun is a monster:
			decrease health of the second noun by result;
			say "You deal [result] damage to [the second noun].";
		Otherwise:
			say "Nothing much else happens.";
	Otherwise:
		continue the action.

Understand "roll [something preferably held]" as rolling. Rolling is an action applying to one visible thing.

Carry out rolling:
	if the noun is a die:
		let result be a random number from 1 to the sides of the noun;
		say "You have rolled [result] on [the noun].";
	Otherwise:
		say "[the noun] cannot be rolled.".

To decide whether taco interests Reg the Good Werewolf:
	if Reg the Good Werewolf has taco, no;
	yes.

To decide whether wand interests Reg the Good Werewolf:
	if Reg the Good Werewolf has wand, no;
	yes.

Understand "slap [something]" as slapping. Slapping is an action applying to one visible thing.
Carry out slapping when the noun is a person:
	say "You viciously slap [the noun]!".

Understand "poke [something]" as poking. Poking is an action applying to one visible thing.
Carry out poking when the noun is a person:
	say "You poke [the noun]."

Before reading a command:
	let N be "[the player's command]";
	if N is "take over kingdom",
		say "What kingdom, you dumple!?";
	if N is "take over world",
		say "Sorry, Brain!".


Chapter 6 - The Game

Act I is a scene. Act I begins when play begins. Act I ends when the player has the tetrahedron or the player has the hexahedron or the player has the octohedron or the player has the decahedron or the player has the dodecahedron.

After going to a room (called new room) while Act I is happening:
	If new room is Reg's House Living Room and new room is unvisited:
		say "Reg looks at you closely and squints his eyes. He says 'Yup! You'll have to do. The boogeyman has stolen a magic wand and we need to get it back. To stop him and his minions, you need to find the magic dice.'";
	Otherwise:
		If new room is Briley's Bedroom and new room is unvisited:
			say "Ouch! You stepped on the [tetrahedron] with bare feet! That's going to leave a mark. Better look around to see what happened.";
		Otherwise:
			continue the action.

The player is in Reg's House Living Room.

Act II is a scene. Act II begins when Act I ends. Act II ends when the player has the golden earrings.

When Act II begins:
	say "Once chose a Platonic solids, you are immediately transported to a spooky graveyard.";
	move the player to the Graveyard Entrance.

Act III is a scene. Act III begins when Act II ends. Act III ends when the player has the taco and the player has the wand.

When Act III begins:
	say "Once you pick up the golden earrings, you are transported to the Boogeyman's House! Be careful!";
	move the player to the Boogeyman's House.

Act IV is a scene. Act IV begins when Act III ends.

When Act IV begins:
	say "You have picked up all the items that Reg the Good Werewolf could possibly want. You walk to Reg's house and enter the front door.";
	move the player to the Reg's House Living Room.

Every turn while Act IV is happening:
	If Reg the Good Werewolf has taco and Reg the Good Werewolf has wand:
		say "Reg looks at you. He smiles. Reg says 'Thank you for returning my wand to me. Also, you brought me my favorite food: tacos!'";
		end the story.

Every turn:
	If the monster (called unhealthy one) is dead and the location of unhealthy one is the location of the player:
		if unhealthy one is the 100 ft undead gorilla:
			move the golden earrings to the location of the player;
			say "The gorilla explodes everywhere, leaving behind [golden earrings]!";
		if unhealthy one is Boogeyman:
			move the taco to the location of the player;
			move the wand to the location of the player;
			say "The boogeyman explodes into a thousands sparkles of light, leaving behind [taco] and [wand].";
		remove unhealthy one from play;
		now health of unhealthy one is 100;
	If location of skeleton is location of player or location of ghost is location of player:
		let chance to hit be a random number from 1 to 100;
		let damage be a random number from 1 to 5;
		if chance to hit < 21:
			decrease the health of the player by damage;
			say "You take [damage] points of damage from the monster in the room!";
	If location of the undead gorilla is location of player:
		let chance to hit be a random number from 1 to 100;
		let damage be a random number from 1 to 6;
		if chance to hit < 21:
			decrease the health of the player by damage;
			say "You take [damage] points of damage from the monster in the room!";
	If location of boogeyman is location of player and the player is not wearing golden earrings:
		let chance to hit be a random number from 1 to 100;
		let damage be a random number from 1 to 6;
		if chance to hit < 21:
			decrease the health of the player by damage;
			say "You take [damage] points of damage from the monster in the room!";
	If the player is dead:
		say "I am sorry, but you died!";
		end the story.