chroniclesofreg/kidnappedfairy.materials/Extensions/William Moore/1PD6 Kidnapped Fairy Setting.i7x

Version 1.0.0 of 1PD6 Kidnapped Fairy Setting by William Moore begins here.

Chapter 1 - Values

Game Turns is a number that varies.
A person has a number called strength.
A person has a number called defense.
A person has a number called health.
A person has a number called damage.
A person has a number called experience.
A person has a number called dice pool.

Chapter 2 - Actions

Understand "stats" as stats. Stats is an action applying to nothing.
Carry out stats:
	say "[bold type]dice pool:[roman type] [the dice pool of the player][line break]";
	say "[bold type]strength:[roman type] [the strength of the player][line break]";
	say "[bold type]defense:[roman type] [the defense of the player][line break]";
	say "[bold type]experience points:[roman type] [the experience of the player][line break]";

Understand "reroll" as rerolling. Rerolling is an action applying to nothing.
Carry out rerolling while the location of the player is Reg's Front Yard:
	Now the dice pool of a player is 1;
	Let new health be a random number from 1 to 6;
	Now the health of a player is new health;
	Let new strength be a random number from 1 to 6;
	Now the strength of a player is new strength;
	Let new defense be a random number from 1 to 6;
	Now the defense of a player is new defense.

Understand "buy dice" as buying dice. Buying dice is an action applying to nothing.
Carry out buying dice:
	if the experience of the player is greater than 49:
		increase the dice pool of the player by 1;
		decrease the experience of the player by 50;
		say "You have purchased one die for your dice pool!";
	otherwise:
		say "You do not have enough experience to purchase a die!".

Understand "buy strength" as buying strength. Buying strength is an action applying to nothing.
Carry out buying strength:
	if the experience of the player is greater than 9 and the strength of the player is less than 6:
		increase the strength of the player by 1;
		decrease the experience of the player by 10;
		say "You have purchased one to your strength!";
	otherwise:
		if the strength of the player is 6:
			say "You have maxed out your strength.";
		otherwise:
			say "You do not have enough experience to purchase strength!".

Understand "buy defense" as buying defense. Buying defense is an action applying to nothing.
Carry out buying defense:
	if the experience of the player is greater than 9 and the defense of the player is less than 6:
		increase the defense of the player by 1;
		decrease the experience of the player by 10;
		say "You have purchased one to your defense!";
	otherwise:
		if the defense of the player is 6:
			say "You have maxed out your defense.";
		otherwise:
			say "You do not have enough experience to purchase defense!".

Understand "buy health" as buying health. Buying health is an action applying to nothing.
Carry out buying health:
	if the experience of the player is greater than 9:
		increase the health of the player by 1;
		increase the experience of the player by 10;
		say "You have purchased one to your health!";
	otherwise:
		say "You do not have enough experience to purchase health!".

Instead of attacking when the noun is a monster:
	if the damage of the noun <= health of the noun:
		let encounter roll be strength of player;
		repeat with die running from 1 to dice pool of player:
			let die roll be a random number from 1 to 6;
			increase encounter roll by die roll;
		decrease encounter roll by defense of the noun;
		if encounter roll is less than 0:
			let encounter roll be 0;
		say "You exclaim 'You're going into space, [the noun]!'";
		increase the damage of the noun by encounter roll;
		let encounter roll be strength of the noun;
		repeat with die running from 1 to dice pool of the noun:
			let die roll be a random number from 1 to 6;
			increase encounter roll by die roll;
		decrease encounter roll by defense of the player;
		if encounter roll is less than 0:
			let encounter roll be 0;
		increase the damage of the player by encounter roll;
		if the damage of the noun is greater than the health of the noun:
			say "[the noun] looks stunned as they go flying into space.";
			increase the experience of the player by experience of the noun;
			remove the noun from play.

Instead of attacking when the noun is a person and the noun is not the player and the noun is not a monster:
	say "For whatever it is worth, you punch [the noun].".

Instead of attacking when the noun is a person and the noun is the player:
	say "For whatever it is worth, you punch yourself.".

Chapter 3 - Added Game Flow

When play begins:
	Now the right hand status line is "[bold type]DMG/HP:[roman type] [the damage of the player]/[the health of the player][line break]";
	Now the dice pool of a player is 1;
	Let new health be a random number from 1 to 6;
	Now the health of a player is new health;
	Let new strength be a random number from 1 to 6;
	Now the strength of a player is new strength;
	Let new defense be a random number from 1 to 6;
	Now the defense of a player is new defense.

Every turn:
	increase Game Turns by 1;
	if Game Turns is 50:
		now Game Turns is 0;
		increase the experience of the player by 1;
	If the damage of the player >= the health of the player:
		say "You tried your best at punching, but Reg passed into the great beyond. Try harder next time.";
		end the story.

1PD6 Kidnapped Fairy Setting ends here.

---- DOCUMENTATION ----
[ Copyright (C) 2022  William R. Moore <william@nerderium.com>

	This program is free software: you can redistribute it and/or modify
	it under the terms of the GNU General Public License as published by
	the Free Software Foundation, version 3 of the License.

	This program is distributed in the hope that it will be useful,
	but WITHOUT ANY WARRANTY; without even the implied warranty of
	MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
	GNU General Public License for more details.

	You should have received a copy of the GNU General Public License
	along with this program. If not, see <https://www.gnu.org/licenses/>. ]